Abi vaja.

Vaata eelmist teemat Vaata järgmist teemat Go down

Impossible.
Impossible.
Juunior
Liitus : 22/03/2015
Postitusi : 11

PostitamineImpossible. on 24.03.15 20:42

Tervist, selline probleem, et oleks vaja serverile pb vipmenu, kus oleks 1) Gravity 2) Elud 3)Unlimited Ammo 4) Silent walk
Ei leidnud ise, sp küsingi abi. Oleks tänulik kui keegi teeks või aitaks vähemalt.

Ette tänades: Impossible. :)
Tonight
Tonight

Abi vaja. Vetera11
Liitus : 19/02/2012
Postitusi : 17121

PostitamineTonight on 24.03.15 21:06

Kood:
#include <amxmodx>
#include <amxmisc>
#include <colorchat>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define PLUGIN "Paintball VIP"
#define VERSION "2.1"
#define AUTHOR "QzeT"

new const Prefix[ ] = "^04[VIPMenüü]^01"

new bool:Unlimited[33]

new Gravity, Elud

public plugin_init() {
   register_plugin(PLUGIN, VERSION, AUTHOR)
   
   register_event( "CurWeapon", "RelvaEvent", "be", "1=1")
   RegisterHam(Ham_Spawn, "player", "Spawnimine", 1)
   RegisterHam(Ham_Spawn, "player", "VIPMenu", 1)
   
   Gravity            = register_cvar("amx_gravity",       "0.6")
   Elud               = register_cvar("amx_elud",           "100")
}

public VIPMenu(id)
{
   if(get_user_flags(id) & ADMIN_LEVEL_H)
   {
      new menu = menu_create("VIPMenüü", "VIPMenyHandler")
      
      menu_additem(menu, "Gravity", "1", 0)
      menu_additem(menu, "Elud", "2", 0)
      menu_additem(menu, "Unlimited Ammo", "3", 0)
      menu_additem(menu, "Silent Walk", "4", 0)
      
      menu_setprop(menu, MPROP_EXIT, MEXIT_ALL)
      menu_display(id, menu)
   }
}

public VIPMenyHandler(id, menu, item)
{
   if(!is_user_alive(id))
   {
      menu_destroy(menu)
      return PLUGIN_HANDLED
   }
   
   if(item == MENU_EXIT)
   {
      menu_destroy(menu)
      return PLUGIN_HANDLED
   }
   
   new data[6], szName[64];
   new access, callback;
   menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
   new key = str_to_num(data);
   switch(key)
   {
   case 1:{
         set_user_gravity(id, get_pcvar_float(Gravity))
         ColorChat(id, NORMAL, "%s Võtsid ^3Gravity^1.", Prefix)
      }
   case 2:{
         set_user_health(id, get_pcvar_num(Elud))
         ColorChat(id, NORMAL, "%s Võtsid ^3Elud^1.", Prefix)
      }    
   case 3:{
         Unlimited[id] = true
         ColorChat(id, NORMAL, "%s Võtsid ^3Unlimited Ammo^1.", Prefix)
      }
   case 4:{
         set_user_footsteps(id, 1)
         ColorChat(id, NORMAL, "%s Võtsid ^3Silent Walki^1.", Prefix)
      }
   }
   menu_destroy(menu)
   return PLUGIN_HANDLED
}

public RelvaEvent(id)
{
   if(Unlimited[id])
   {
      new iClip, iAmmo, iWeapName[33]
      new iWeap = get_user_weapon(id, iClip, iAmmo)
      get_weaponname(iWeap, iWeapName, 32)
      
      if(iWeap == CSW_KNIFE ||
            iWeap == CSW_HEGRENADE ||
            iWeap == CSW_SMOKEGRENADE ||
            iWeap == CSW_FLASHBANG ){
         return PLUGIN_HANDLED
      }
      
      new bpammo = cs_get_user_bpammo(id, iWeap)
      if (bpammo <= 199 ) {
         cs_set_user_bpammo(id, iWeap, 200)
      }
   }
   return PLUGIN_HANDLED
}

public Spawnimine(id)
{
   if (is_user_alive(id))
   {
      set_user_footsteps(id, 0)
      set_user_gravity(id, 1.0)
      Unlimited[id] = false
   }
}
Impossible.
Impossible.
Juunior
Liitus : 22/03/2015
Postitusi : 11

PostitamineImpossible. on 25.03.15 16:42

Aitäh, aga kuhu ma selle lisan täpsemalt ?
Tonight
Tonight

Abi vaja. Vetera11
Liitus : 19/02/2012
Postitusi : 17121

PostitamineTonight on 25.03.15 16:55

1) Tee .sma https://www.faval.eu/t876-sma-faili-tegemine
(Kui sa pole varem compilinud, siis tõmba ka colorchat.inc)
2) Compile'i see .amxxiks https://www.faval.eu/t434-oma-arvutis-plugina-compilimine
Impossible.
Impossible.
Juunior
Liitus : 22/03/2015
Postitusi : 11

PostitamineImpossible. on 25.03.15 18:59

Aga mul ei ole seal compile'i.exe miskipärast. Mis tegema peaksin?
Tonight
Tonight

Abi vaja. Vetera11
Liitus : 19/02/2012
Postitusi : 17121

PostitamineTonight on 26.03.15 5:59

Tõmba full installer oma arvutisse: http://www.amxmodx.org/downloads.php

Vaata eelmist teemat Vaata järgmist teemat Tagasi üles

Soovid reklaamidest vabaneda?

Selleks logi sisse või tee endale kasutaja.

Liitu foorumiga

Tee endale kasutaja ning osale aruteludes.


Tee uus kasutaja

Logi sisse

Omad foorumis juba kasutajat? Logi sisse.


Logi sisse

 
Permissions in this forum:
Sa ei saa vastata siinsetele teemadele